home *** CD-ROM | disk | FTP | other *** search
/ Amiga Plus 2002 #3 / Amiga Plus CD - 2002 - No. 03.iso / AmiSoft / Game / Misc / Skeleton.lha / Skeleton / files / skel-pal.asm < prev    next >
Encoding:
Assembly Source File  |  2002-10-24  |  26.4 KB  |  1,366 lines
  1.     PROCESSOR 6502
  2.     INCLUDE    "VCS.H"
  3.  
  4.     INCLUDE "SKELRAM.ASM"
  5.  
  6.     SEG    ROM
  7.     ORG    $1000
  8.  
  9.     DC.B    "Skeleton (c)2002 Eric Ball",0
  10.  
  11. KERN0    STA    WSYNC        ;56-0
  12.     LDA    (MAZE0L),Y    ;-5
  13.     STA    PF0        ;-8
  14.     CPY    BALLTOP        ;-10
  15.     BCC    WAIT0        ;-12/13
  16.     CPY    BALLBOT        ;-14
  17.     BCS    WAIT0        ;-16/17
  18.     LDA    #2        ;-18
  19. WAIT0    STA    ENABL        ;-21
  20.     STX    PF1        ;-24
  21.     STX    PF2        ;-27
  22.     LDA    (MAZE0R),Y    ;-32
  23.     STA    PF0        ;-35
  24.     INY            ;-37
  25.     LDA    WALL        ;-40
  26.     CMP    #1        ;-42
  27.     BEQ    WALL15        ;-44/45
  28.     CPY    #24        ;-46
  29.     BNE    KERN0        ;-48/49
  30.     BEQ    KERN20        ;-51
  31. WALL15    CPY    #18        ;-47
  32.     BCC    KERN0        ;-49/50
  33.     LDX    #$FF        ;-51
  34.     CPY    #24        ;-53
  35.     BNE    KERN0        ;-55/56
  36.  
  37. WALL20    STA    WSYNC        ;44-0
  38.     LDA    #$80        ;-2
  39.     STA    PF0        ;-5
  40.     LDA    #$00        ;-7
  41.     STA    PF1        ;-10
  42.     STA    PF2        ;-13
  43.     LDX    #204-24        ;-15
  44.     JSR    XWALL        ;-21
  45.     DEX            ;36-38
  46.     JMP    KERN170        ;-41
  47.  
  48. KERN20    STA    WSYNC        ;72-0
  49.     TXA            ;-2
  50.     AND    #$0F        ;-4
  51.     ORA    (MAZE1L),Y    ;-9
  52.     STA    PF1        ;-12
  53.     STX    PF2        ;-15
  54.     LDX    #$80        ;-17
  55.     STX    PF0        ;-20
  56.     LDX    #4        ;-22
  57. WAIT20    DEX            ;+2
  58.     BNE    WAIT20        ;+2/3
  59.     AND    #$0F        ;41-43
  60.     ORA    (MAZE1R),Y    ;-48
  61.     STA    PF1        ;-51
  62.     INY            ;-53
  63.     LDA    WALL        ;-56
  64.     CMP    #2        ;-58
  65.     BEQ    WALL35        ;-60/61
  66.     CPY    #48        ;-62
  67.     BNE    KERN20        ;-64/65
  68.     BEQ    KERN40        ;-67
  69. WALL35    CPY    #42        ;61-63
  70.     BCC    KERN20        ;-65/66
  71.     DEX            ;-67
  72.     CPY    #48        ;-69
  73.     BNE    KERN20        ;-71/72
  74.  
  75. WALL40    STA    WSYNC        ;41-0
  76.     LDA    #$10        ;-2
  77.     STA    PF1        ;-5
  78.     LDA    #$00        ;-7
  79.     STA    PF2        ;-10
  80.     LDX    #180-48        ;-12
  81.     JSR    XWALL        ;-18
  82.     DEX            ;36-38
  83.     JMP    KERN150        ;-41
  84.  
  85. KERN40    STA    WSYNC        ;72-0
  86.     LDA    (MAZE2L),Y    ;-5
  87.     STA    PF1        ;-8
  88.     STX    PF2        ;-11
  89.     LDX    #5        ;-13
  90.     CPY    SKELTOP        ;-15
  91.     BCC    WAIT40        ;-17/18
  92.     LDA    (SKEL0),Y    ;-22
  93.     STA    GRP0        ;-24
  94.     LDA    (SKEL1),Y    ;-29
  95.     STA    GRP1        ;-32
  96.     LDX    #2        ;-34
  97. WAIT40    DEX            ;+2
  98.     BNE    WAIT40        ;+2/3
  99.     LDA    (MAZE2R),Y    ;42/43-47/48
  100.     STA    PF1        ;-50/51
  101.     INY            ;-53
  102.     LDA    WALL        ;-56
  103.     CMP    #3        ;-58
  104.     BEQ    WALL55        ;-60/61
  105.     CPY    #72        ;-62
  106.     BNE    KERN40        ;-64/65
  107.     LDA    #$00        ;-66
  108.     BEQ    KERN60        ;-69
  109. WALL55    CPY    #66        ;61-63
  110.     BCC    KERN40        ;-65/66
  111.     DEX            ;-67
  112.     CPY    #72        ;-69
  113.     BNE    KERN40        ;-71/72
  114.  
  115. WALL60    STA    WSYNC        ;41-0
  116.     LDA    #$11        ;-2
  117.     STA    PF1        ;-5
  118.     LDA    #$00        ;-7
  119.     STA    PF2        ;-10
  120.     LDX    #156-72        ;-12
  121.     JSR    XWALL        ;-18
  122.     DEX            ;36-38
  123.     JMP    KERN130        ;-41
  124.  
  125.     ; 18 
  126. PVIEW1    INX            ; center view subroutine
  127.     TYA            ; move forward one step
  128.     CLC
  129.     ADC    PLAYDIR
  130.     CMP    SKELPOS        ; check skeleton position
  131.     BNE    PVIEW2
  132.     STX    SKELDIS        ; save if found
  133. PVIEW2    TAY            ; check for wall
  134.     LDA    LVLMASK
  135.     AND    MAZES,Y        ; BNE done after return
  136.     RTS
  137.  
  138. WAIT60    LDX    #3        ;20-22
  139. WAIT61    DEX            ;+2
  140.     BNE    WAIT61        ;+2/3
  141.     BEQ    KERN61        ;36-39
  142.  
  143. KERN60    STA    WSYNC        ;70-0
  144.     AND    #$F0        ;-2
  145.     ORA    (MAZE3L),Y    ;-7
  146.     STA    PF2        ;-10
  147.     LDX    #$11        ;-12
  148.     STX    PF1        ;-15
  149.     CPY    SKELTOP        ;-17
  150.     BCC    WAIT60        ;-19/20
  151.     TAX            ;-21
  152.     LDA    (SKEL0),Y    ;-26
  153.     STA    GRP0        ;-29
  154.     LDA    (SKEL1),Y    ;-34
  155.     STA    GRP1        ;-37
  156.     TXA            ;-39
  157. KERN61    AND    #$F0        ;39-41
  158.     ORA    (MAZE3R),Y    ;-46
  159.     STA    PF2        ;-49
  160.     INY            ;-51
  161.     LDA    WALL        ;-54
  162.     CMP    #4        ;-56
  163.     BEQ    WALL75        ;-58/59
  164.     CPY    #96        ;-60
  165.     BNE    KERN60        ;-62/63
  166.     BEQ    KERN80        ;-65
  167. WALL75    CPY    #90        ;59-61
  168.     BCC    KERN60        ;-63/64
  169.     LDA    #$FF        ;-65
  170.     CPY    #96        ;-67
  171.     BNE    KERN60        ;-69/70
  172.  
  173. KERN80    STA    WSYNC        ;36-0
  174.     LDA    #$08        ;-2
  175.     STA    PF2        ;-5
  176.     LDX    #132-96        ;-7
  177.     JSR    XWALL        ;-13
  178.     DEX            ;36-38
  179.  
  180. KERN110    STA    WSYNC        ;56-0
  181.     LDA    (MAZE3L),Y    ;-5
  182.     STA    PF2        ;-8
  183.     LDX    #4        ;-10
  184.     CPY    SKELBOT        ;-12
  185.     BCS    WAIT110        ;-14/15
  186.     LDA    (SKEL0),Y    ;-19
  187.     STA    GRP0        ;-22
  188.     LDA    (SKEL1),Y    ;-27
  189.     STA    GRP1        ;-30
  190.     LDX    #1        ;-32
  191. WAIT110    DEX            ;+2
  192.     BPL    WAIT110        ;+2/3
  193.     LDA    (MAZE3R),Y    ;39/41-44/46
  194.     STA    PF2        ;-47/49
  195.     INY            ;-51
  196.     CPY    #156        ;-53
  197.     BNE    KERN110        ;-55/56
  198.  
  199. KERN130    STA    WSYNC        ;64-0
  200.     LDA    (MAZE2L),Y    ;-5
  201.     STA    PF1        ;-8
  202.     STX    PF2        ;-10
  203.     LDX    #4        ;-12
  204.     CPY    SKELBOT        ;-14
  205.     BCS    WAIT130        ;-16/17
  206.     LDA    (SKEL0),Y    ;-21
  207.     STA    GRP0        ;-24
  208.     LDA    (SKEL1),Y    ;-29
  209.     STA    GRP1        ;-32
  210.     LDX    #1        ;-34
  211. WAIT130    DEX            ;+2
  212.     BPL    WAIT130        ;+2/3
  213.     LDA    (MAZE2R),Y    ;41/43-46/48
  214.     STA    PF1        ;-49/51
  215.     INY            ;-53
  216.     CPY    #162        ;-55
  217.     BCC    KERN130        ;-57/58
  218.     LDX    #$00        ;-59
  219.     CPY    #180        ;-61
  220.     BNE    KERN130        ;-63/64
  221.     LDX    #$FF        ;-65
  222.  
  223. KERN150    STA    WSYNC        ;64-0
  224.     LDA    (MAZE1L),Y    ;-5
  225.     STA    PF1        ;-8
  226.     STX    PF2        ;-10
  227.     LDX    #4        ;-12
  228.     CPY    SKELBOT        ;-14
  229.     BCS    WAIT150        ;-16/17
  230.     LDA    (SKEL0),Y    ;-21
  231.     STA    GRP0        ;-24
  232.     LDA    (SKEL1),Y    ;-29
  233.     STA    GRP1        ;-32
  234.     LDX    #1        ;-34
  235. WAIT150    DEX            ;+2
  236.     BPL    WAIT150        ;+2/3
  237.     LDA    (MAZE1R),Y    ;41/43-46/48
  238.     STA    PF1        ;-49/51
  239.     INY            ;-53
  240.     CPY    #186        ;-55
  241.     BCC    KERN150        ;-57/58
  242.     LDX    #$00        ;-59
  243.     CPY    #204        ;-61
  244.     BNE    KERN150        ;-63/64
  245.     LDX    #$FF        ;-65
  246.  
  247. KERN170    STA    WSYNC        ;48-0
  248.     LDA    (MAZE0L),Y    ;-5
  249.     STA    PF0        ;-8
  250.     CPY    BALLTOP        ;-10
  251.     BCC    WAIT170        ;-12/13
  252.     CPY    BALLBOT        ;-14
  253.     BCS    WAIT170        ;-16/17
  254.     LDA    #2        ;-18
  255. WAIT170    STA    ENABL        ;-21
  256.     STX    PF1        ;-24
  257.     STX    PF2        ;-27
  258.     LDA    (MAZE0R),Y    ;-32
  259.     STA    PF0        ;-35
  260.     INY            ;-37
  261.     CPY    #210        ;-39
  262.     BCC    KERN170        ;-41/42
  263.     LDX    #$00        ;-43
  264.     CPY    #228        ;-45
  265.     BNE    KERN170        ;-47/48
  266.  
  267. LAST    LDA    #35*76/64+1
  268.     STA    WSYNC        ;-0
  269.     STA    TIM64T        ;-4
  270.     STX    PF0
  271.  
  272.     LDX    SOUNDEL        ; sound countdown
  273.     BEQ    COLUPA        ; already zero?
  274.     DEX
  275.     BNE    COLUPA        ; zero?
  276.     STX    AUDV0        ; turn off sound
  277.     STX    AUDV1
  278.  
  279. COLUPA    STX    SOUNDEL
  280.     LDA    SKELIFE        ; skeleton still alive?
  281.     BPL    COLUPB
  282.     LDX    FIREDEL
  283.     LDA    SKELDIE,X
  284.     BNE    COLUPC
  285.     BEQ    COLUPC
  286. COLUPB    LDA    FIREDEL        ; fire flash?
  287.     CMP    #45
  288.     BCS    FIRETST
  289.     LDA    MAZECOL        ; set playfield colour
  290.     STA    COLUPF
  291.     LDX    SKELIFE        ; set skeleton color
  292.     LDA    LIFELUM,X
  293. COLUPC    STA    COLUP0
  294.     STA    COLUP1
  295.  
  296. FIRETST    LDA    INPT4        ; fire button
  297.     AND    #$80
  298.     CMP    THISFIR        ; debounce
  299.     BNE    PLAYMOV        ; not the same
  300.     LDX    LASTFIR        ; check last button position
  301.     STA    LASTFIR        ; save current
  302.     BPL    PLAYMOV        ; do nothing if last was down
  303.     ASL            ; check current
  304.     BCS    PLAYMOV        ; do nothing if up
  305.     LDA    FIREDEL        ; check reload delay
  306.     BNE    PLAYMOV        ; do nothing if reloading
  307.     STA    AUDF0        ; BANG!
  308.     STA    AUDF1
  309.     LDA    #8        
  310.     STA    AUDC0
  311.     STA    AUDC1
  312.     STA    AUDV0
  313.     STA    AUDV1
  314.     STA    SOUNDEL
  315.     LDA    SKELDIS        ; is skeleton in view?
  316.     AND    #$03
  317.     BEQ    SETDEL        ; not in view
  318.     LDA    #$00        ; make skeleton turn
  319.     SEC            ; and face plaer
  320.     SBC    PLAYDIR
  321.     STA    SKELNXT
  322.     LDA    RANDOM        ; generate random damage
  323.     AND    #$0F        ; 0-15
  324.     STA    FIREDEL        ; save temp
  325.     LDA    SKELIFE        ; reduce skeleton life
  326.     SEC
  327.     SBC    FIREDEL
  328.     STA    SKELIFE
  329.     LDA    FIREDEL        ; set skeleton colour flash
  330.     ASL
  331.     ASL
  332.     ASL
  333.     ASL
  334.     STA    FIREDEL        ; save msn
  335.     LDX    SKELIFE        ; set luminance
  336.     LDA    LIFELUM,X
  337.     ORA    FIREDEL        ; combine
  338.     STA    COLUP0
  339.     STA    COLUP1
  340. SETDEL    LDA    MAZECOL        ; set playfield colour
  341.     AND    #$0F        ; flash maze too
  342.     STA    COLUPF
  343.     LDA    #50        ; set reload timer = 1 sec
  344.     STA    FIREDEL
  345.     BNE    PLAYMOV
  346.  
  347. PLAYMOV    LDA    SWCHA        ; PLAYER MOVE
  348.     ORA    #$0F
  349.     CMP    THISMOV        ; DEBOUNCE
  350.     BNE    SKELMOV
  351.     LDX    LASTMOV        ; moved last frame?
  352.     CPX    #$FF
  353.     BNE    PMOVEA        ; no
  354.     CMP    #$EF        ; forward?
  355.     BEQ    PMOVEC
  356.     CMP    #$7F        ; turn right?
  357.     BEQ    PMOVEB
  358.     CMP    #$BF        ; turn left?
  359.     BNE    SKELMOV
  360.     STA    LASTMOV        
  361.     LDX    PLAYDIR        ; turn left
  362.     LDA    #$00
  363.     SEC
  364.     SBC    PLAYRIG
  365.     STX    PLAYRIG
  366.     STA    PLAYDIR
  367.     BNE    SKELMOV
  368. PMOVEA    CMP    #$FF        ; return to center?
  369.     BNE    SKELMOV
  370.     STA    LASTMOV        ; centered
  371.     BEQ    SKELMOV
  372. PMOVEB    STA    LASTMOV        ; right turn
  373.     LDX    PLAYRIG
  374.     LDA    #$00
  375.     SEC
  376.     SBC    PLAYDIR
  377.     STX    PLAYDIR
  378.     STA    PLAYRIG
  379.     BNE    SKELMOV
  380. PMOVEC    STA    LASTMOV        ; step forward
  381.     LDA    WALL
  382.     CMP    #1
  383.     BEQ    SKELMOV
  384.     LDA    PLAYPOS
  385.     CLC
  386.     ADC    PLAYDIR
  387.     STA    PLAYPOS
  388.     CMP    SKELPOS
  389.     BNE    SKELMOV
  390.     JMP    GOTYOU
  391.  
  392. SKELMOV    LDA    SKELIFE        ; skeleton still alive?
  393.     BMI    SKELSTP
  394.     DEC    SKELDEL        ; main skeleton movement delay
  395.     BEQ    SKDEL1
  396. SKELSTP    JMP    BOTTOM        ; no movement, skip everything
  397.     
  398. SKDEL1    LDA    SKELSEC        ; decrease rate counter
  399.     SEC
  400.     SBC    SKELPER
  401.     STA    SKELSEC
  402.     BCS    SKDEL2        ; no carry = underflow
  403.     ADC    #50
  404.     STA    SKELSEC
  405.     LDA    SKELMIN
  406.     SEC
  407.     SBC    SKELPER        ; decrease square counter
  408.     STA    SKELMIN
  409.     BCS    SKDEL2        ; no carry = underflow
  410.     ADC    #80
  411.     STA    SKELMIN
  412.     LDA    SKELHRS
  413.     SEC
  414.     SBC    SKELPER        ; decrease cube counter
  415.     STA    SKELHRS
  416.     BCS    SKDEL2        ; no carry = underflow
  417.     ADC    #80
  418.     STA    SKELHRS
  419.     DEC    SKELPER        ; speed up skeleton!
  420. SKDEL2    LDA    SKELPER
  421.     STA    SKELDEL 
  422.  
  423.     LDA    SKELNXT        ; forced move?
  424.     BEQ    SMOVEA        ; nope, start the decision tree
  425.     LDX    #0        ; clear forced move flag
  426.     STX    SKELNXT
  427.     CMP    SKELDIR        ; forced=facing?
  428.     BNE     SKNXT0
  429.     JMP    SMOVE1        ; step forward
  430. SKNXT0    STA    SKELDIR        ; turn and set SKELRIG correctly
  431.     CMP    #1
  432.     BEQ    SKNXT1
  433.     BMI    SKNXT2
  434.     LDA    #-1
  435.     STA    SKELRIG
  436.     BNE    SKELSTP
  437. SKNXT1    LDA    #16
  438.     STA    SKELRIG
  439.     BNE    SKELSTP
  440. SKNXT2    CMP    #-1
  441.     BEQ    SKNXT3
  442.     LDA    #1
  443.     STA    SKELRIG
  444.     BNE    SKELSTP
  445. SKNXT3    LDA    #-16
  446.     STA    SKELRIG
  447.     BNE    SKELSTP
  448. SMOVEA    LDX    #0        ; direction flags
  449.     LDA    SKELPOS        ; can we go forward?
  450.     CLC
  451.     ADC    SKELDIR
  452.     TAY
  453.     LDA    LVLMASK
  454.     AND    MAZES,Y
  455.     BNE    SMOVED        ; can't go forward
  456.     INX            ; forward flag
  457.     LDA    #$01        ; determine facing
  458.     BIT    SKELDIR        ; use bit to test for neg too
  459.     BNE    SMOVEB        ; SKELDIR = +1/-1
  460.     LDA    PLAYPOS        ; check for player in same column
  461.     SEC
  462.     SBC    SKELPOS
  463.     AND    #$0F
  464.     BNE    SMOVED
  465.     JMP    SMOVE1
  466. SMOVEB    BMI    SMOVEC        ; SKELDIR = -1
  467.     LDA    PLAYPOS
  468.     SEC
  469.     SBC    SKELPOS
  470.     AND    #$F0        ; player ahead
  471.     BNE    SMOVED
  472.     JMP    SMOVE1
  473. SMOVEC    LDA    SKELPOS        ; player ahead (behind)
  474.     SEC
  475.     SBC    PLAYPOS
  476.     AND    #$F0        ; player ahead
  477.     BNE    SMOVED
  478.     BEQ    SMOVE1
  479. SMOVED    LDA    SKELPOS        ; can we go right?
  480.     CLC
  481.     ADC    SKELRIG
  482.     TAY
  483.     LDA    LVLMASK
  484.     AND    MAZES,Y
  485.     BNE    SMOVEE
  486.     INX
  487.     INX
  488. SMOVEE    LDA    SKELPOS        ; can we go left?
  489.     SEC
  490.     SBC    SKELRIG
  491.     TAY
  492.     LDA    LVLMASK
  493.     AND    MAZES,Y
  494.     BNE    SMOVEF
  495.     INX
  496.     INX
  497.     INX
  498.     INX
  499. SMOVEF    CPX    #0
  500.     BEQ    SMOVE0        ; no directions, turn around
  501.     DEX    
  502.     BEQ    SMOVE1        ; forward only
  503.     DEX
  504.     BEQ    SMOVE2        ; right only
  505.     DEX
  506.     BEQ    SMOVE3        ; right or forward
  507.     DEX
  508.     BEQ    SMOVE4        ; left only
  509.     DEX
  510.     BEQ    SMOVE5        ; left or forward
  511.     DEX
  512.     BEQ    SMOVE6        ; right or left
  513.     BIT    RANDOM        ; all directions    
  514.     BPL    SMOVE1
  515.     BMI    SMOVE6
  516. SMOVE0    LDA    #$00        ; turn around
  517.     SEC
  518.     SBC    SKELDIR
  519.     STA    SKELDIR
  520.     LDA    #$00
  521.     SEC
  522.     SBC    SKELRIG
  523.     STA    SKELRIG
  524.     JMP    BOTTOM
  525. SMOVE2    LDX    SKELRIG        ; turn right
  526.     LDA    #$00
  527.     SEC
  528.     SBC    SKELDIR
  529.     STX    SKELDIR
  530.     STA    SKELRIG
  531.     STX    SKELNXT        ; force forward
  532.     JMP    BOTTOM
  533. SMOVE3    BIT    RANDOM
  534.     BPL    SMOVE1
  535.     BMI    SMOVE2
  536. SMOVE4    LDX    SKELDIR        ; turn left
  537.     LDA    #$00
  538.     SEC
  539.     SBC    SKELRIG
  540.     STX    SKELRIG
  541.     STA    SKELDIR
  542.     STA    SKELNXT        ; force forward
  543.     JMP    BOTTOM
  544. SMOVE5    BIT    RANDOM
  545.     BPL    SMOVE1
  546.     BMI    SMOVE4
  547. SMOVE6    BIT    RANDOM
  548.     BVC    SMOVE2
  549.     BVS    SMOVE4
  550. SMOVE1    LDA    SKELPOS        ; step forward
  551.     CLC
  552.     ADC    SKELDIR
  553.     STA    SKELPOS
  554.     CMP    PLAYPOS
  555.     BNE    SMOVE7
  556.     JMP    GOTYOU
  557. SMOVE7    LDA    SOUNDEL        ; check for existing sound
  558.     BNE    BOTTOM
  559.     JSR    SKPOSXY        ; calculate distance for sound
  560.     JSR    PDIRXY
  561.     JSR    SKSTEP
  562.     LDA    #1
  563.     STA    AUDC0
  564.     STA    AUDC1
  565.     LDA    RANDOM
  566.     ORA    #30
  567.     STA    AUDF0
  568.     STA    AUDF1
  569.     CPX    #-15
  570.     BPL    AUDX
  571.     LDX    #-15
  572. AUDX    STX    AUDV0        ; left speaker
  573.     CPY    #-15
  574.     BPL    AUDY
  575.     LDY    #-15
  576. AUDY    STY    AUDV1        ; right speaker
  577.     LDA    SKELDEL
  578.     LSR
  579.     STA    SOUNDEL
  580.  
  581. BOTTOM    JSR    DOVSYNC
  582.  
  583. NEWSKEL    LDA    SKELIFE        ; skeleton dead?
  584.     BPL    PVIEW
  585.     LDA    FIREDEL        ; done death flash?
  586.     BNE    PVIEW
  587.     LDX    SKELNUM        ; increment skeleton life
  588.     INX
  589.     STX    SKELNUM
  590.     STX    SKELIFE
  591.     LDX    MAZECOL        ; increment maze luminance
  592.     INX
  593.     TXA
  594.     AND    #$0F
  595.     CMP    #13
  596.     BEQ    NEXTLVL        ; ten down, new level
  597.     STX    MAZECOL
  598.     LDA    #$00
  599.     STA    SKELPOS
  600.     JSR    SKPOSXY        ; figure out restart position
  601. ;    LDA    SKELX
  602.     BPL    NEWSK1
  603.     EOR    #$FF        ; NEG
  604.     CLC
  605.     ADC    #$01
  606. NEWSK1    BIT    SKELY
  607.     BPL    NEWSK2
  608.     SEC
  609.     SBC    SKELY
  610.     BPL    NEWSK3
  611. NEWSK2    CLC
  612.     ADC    SKELY
  613. NEWSK3    CMP    #$07
  614.     BPL    NEWSK4
  615.     LDA    #120
  616.     STA    SKELPOS
  617. NEWSK4    LDX    #LOADDEL-LOADRAM; reset skeleton move timers
  618.     BNE    REINIT
  619. NEXTLVL    TXA            ; increment maze colour
  620.     CLC
  621.     ADC    #$16
  622.     STA    MAZECOL
  623.     LDX    #LOADLVL-LOADRAM
  624.     ASL    LVLMASK
  625.     BNE    REINIT
  626.     JMP    YOUWIN
  627.  
  628. REINIT    LDA    LOADRAM-1,X    ; refresh initial values
  629.     STA    RAMLOAD-1,X
  630.     DEX
  631.     BNE    REINIT
  632.  
  633. PVIEW    LDX    #0        ; center view & skeleton distance
  634.     STX    SKELDIS
  635.     LDY    PLAYPOS
  636.     JSR    PVIEW1
  637.     BNE    PVIEWA
  638.     JSR    PVIEW1
  639.     BNE    PVIEWA
  640.     JSR    PVIEW1
  641.     BNE    PVIEWA
  642.     JSR    PVIEW1
  643.     BNE    PVIEWA
  644.     INX
  645. PVIEWA    STX    WALL        ; save wall distance
  646.     LDA    PLAYPOS        ; right view, step 1
  647.     CLC
  648.     ADC    PLAYRIG
  649.     LDX    #MAZE1R+1    ; save bits here
  650. PVIEWE    JSR    PVIEW3        ; test and save bits
  651.     CPX    #MAZE3R+2
  652.     BNE    PVIEWE
  653.     LDA    PLAYPOS        ; left view, step 1
  654.     SEC            ;
  655.     SBC    PLAYRIG        ;
  656.     LDX    #MAZE1L+1    ; save bits here
  657. PVIEWF    JSR    PVIEW3        ;
  658.     CPX    #MAZE3L+2    ;
  659.     BNE    PVIEWF        ;
  660.     LDX    #MAZE1R+1    ; right view, step 2
  661.     LDY    #MAZE0R        ; 
  662. PVIEWG    JSR    PVIEW4        ; change bits to pointers
  663.     CPY    #MAZE3R+2    ;
  664.     BNE    PVIEWG        ;
  665.     LDX    #MAZE1L+1    ; left view, step 2
  666.     LDY    #MAZE0L        ;
  667. PVIEWH    JSR    PVIEW4        ; change bits to pointers
  668.     CPY    #MAZE3L+2    ;
  669.     BNE    PVIEWH        ;
  670.  
  671.     LDA    SWCHB        ; check difficulty switch
  672.     AND    #$40
  673.     BEQ    DOBALL
  674.     STA    BALLTOP        ; set top & bottom same
  675.     STA    BALLBOT        ; to prevent ball display
  676.     BNE    NOBALL
  677. DOBALL    JSR    SKPOSXY        ; add skeleton direction pointer
  678.     JSR    PDIRXY
  679.     JSR    POSBALL    
  680.  
  681. NOBALL    LDA    SKELDIS        ; skeleton view
  682.     AND    #$03        ; check distance
  683.     BNE    SKPOSA
  684.     STA    SKELBOT        ; force skeleton off
  685.     SBC    #1        ; by reversing top & bottom
  686.     STA    SKELTOP
  687.     JMP    SKVIEW0
  688. SKPOSA    SEC            ; decrement for table access
  689.     SBC    #1
  690.     ASL            ; multiply by 16
  691.     ASL
  692.     ASL
  693.     ASL
  694.     TAY
  695.     LDA    SKTABLE,Y    ; use table to update RAM
  696.     STA    HMCLR
  697.     STA    HMP0
  698.     LDA    SKTABLE+1,Y
  699.     STA    SKELTOP
  700.     LDA    SKTABLE+2,Y
  701.     STA    SKELBOT
  702.     LDA    SKTABLE+3,Y
  703.     STA    NUSIZ0
  704.     STA    NUSIZ1
  705.     LDA    PLAYDIR        ; figure out facing
  706.     CMP    SKELDIR
  707.     BEQ    SKPOSB        ; same dir = back
  708.     CMP    SKELRIG        ; left
  709.     BEQ    SKPOSC
  710.     CLC
  711.     ADC    SKELDIR
  712.     BEQ    SKPOSD        ; inverse = front
  713.     LDA    SKTABLE+8,Y    ; must be right
  714.     STA    SKEL1        ; arm on the right
  715.     LDA    SKTABLE+9,Y
  716.     STA    SKEL1+1
  717.     LDA    SKTABLE+10,Y    ; body on the left
  718.     STA    SKEL0
  719.     LDA    SKTABLE+11,Y
  720.     STA    SKEL0+1
  721.     LDA    #$18        ; mirror both
  722.     BNE    SKVIEW
  723. SKPOSB    LDA    SKTABLE+6,Y    ; back for both
  724.     STA    SKEL0        
  725.     STA    SKEL1        
  726.     LDA    SKTABLE+7,Y    
  727.     STA    SKEL0+1        
  728.     STA    SKEL1+1        
  729.     LDA    #$08        ; left normal, right mirror
  730.     BNE    SKVIEW
  731. SKPOSC    LDA    SKTABLE+8,Y    ; arm on the left
  732.     STA    SKEL0
  733.     LDA    SKTABLE+9,Y
  734.     STA    SKEL0+1
  735.     LDA    SKTABLE+10,Y    ; body on the right
  736.     STA    SKEL1
  737.     LDA    SKTABLE+11,Y
  738.     STA    SKEL1+1
  739.     LDA    #$00        ; no mirror
  740.     BEQ    SKVIEW
  741. SKPOSD    LDA    SKTABLE+4,Y    ; front for both
  742.     STA    SKEL0
  743.     STA    SKEL1
  744.     LDA    SKTABLE+5,Y
  745.     STA    SKEL0+1
  746.     STA    SKEL1+1
  747.     LDA    #$08        ; left normal, right mirror
  748. SKVIEW    STA    WSYNC        ; hmove P0 for size
  749.     STA    HMOVE
  750.     STA    REFP1        ; set reflection registers
  751.     LSR
  752.     STA    REFP0
  753.     STA    WSYNC
  754.     STA    HMOVE
  755.  
  756. SKVIEW0    JSR    WAITIM
  757.  
  758.     LDA    INPT4        ; save button for debounce
  759.     AND    #$80
  760.     STA    THISFIR
  761.     LDX    FIREDEL        ; decrement reload counter
  762.     BEQ    RELOAD
  763.     DEX
  764.     STX    FIREDEL
  765.  
  766. RELOAD    LDA    SWCHA        ; save joystick for debounce
  767.     ORA    #$0F
  768.     STA    THISMOV
  769.  
  770.     LDY    #$00
  771.     LDX    #$00
  772.     JMP    KERN0
  773.  
  774.     ; 44
  775. SKTABLE    DC.B    $70, 83, 192, $07
  776.     DC.W    SKFRON1-83, SKBACK1-83
  777.     DC.W    SKARM1-83, SKBODY1-83
  778.     DC.B    $45, $72, $69, $63
  779.     DC.B    $F0, 95, 168, $05
  780.     DC.W    SKFRON2-95, SKBACK2-95
  781.     DC.W    SKARM2-95, SKBODY2-95
  782.     DC.B    $42, $61, $6C, $6C
  783.     DC.B    $B0, 107, 144, $00
  784.     DC.W    SKFRON3-107, SKBACK3-107
  785.     DC.W    SKARM3-107, SKBODY3-107
  786.  
  787.     ; 37
  788. XWALL0    STA    WSYNC        ;46-0
  789.     LDA    #0        ;-2
  790.     CPY    BALLTOP        ;-4
  791.     BCC    XWALL1        ;-6/7
  792.     CPY    BALLBOT        ;-8
  793.     BCS    XWALL1        ;-10/11
  794.     LDA    #2        ;-12
  795. XWALL1    STA    ENABL        ;-15
  796. XWALL    CPY    SKELTOP        ;-17
  797.     BCC    XWALL2        ;-19/20
  798.     CPY    SKELBOT        ;-21
  799.     BCS    XWALL2        ;-23/24
  800.     LDA    (SKEL0),Y    ;-28
  801.     STA    GRP0        ;-31
  802.     LDA    (SKEL1),Y    ;-36
  803.     STA    GRP1        ;-39
  804. XWALL2    INY            ;-41
  805.     DEX            ;-43
  806.     BNE    XWALL0        ;-45/46
  807.     RTS            ;-51
  808.  
  809.     ; 12            
  810. RAND    LDA    RANDOM        ; simple 8 bit LFSR
  811.     BEQ    XSEED        ;+5/6
  812.     LSR            ;+7
  813.     BCC    SRAND        ;+9/10
  814. XSEED    EOR    #$A9        ;+6/9-8/11
  815. SRAND    STA    RANDOM        ;+8/10/11-11/14
  816.     RTS            ;+17/20
  817.  
  818.     ; 59
  819. POSBALL    TXA            ; SKELX/Y into BALLTOP/BOT & RESBL
  820.     BEQ    PBALL1
  821.     BMI    PBALL2
  822.     LDA    #3
  823.     BNE    PBALL3
  824. PBALL1    LDA    #108
  825.     BNE    PBALL3
  826. PBALL2    LDA    #213
  827. PBALL3    STA    BALLTOP
  828.     CLC
  829.     ADC    #12
  830.     STA    BALLBOT
  831.     TYA
  832.     BEQ    PBALL4
  833.     BPL    PBALL5
  834.     LDA    #$60
  835.     LDY    #3
  836.     BNE    PBALL6
  837. PBALL4    LDA    #$40
  838.     LDY    #6
  839.     BNE    PBALL6
  840. PBALL5    LDA    #$20
  841.     LDY    #9
  842. PBALL6    STY    WSYNC        ; -0
  843.     STY    RESBL        ; -3
  844. PBALL0    DEY            ; +2
  845.     STY    RESBL        ; +3
  846.     BNE    PBALL0        ; +2/3
  847.     STA    WSYNC
  848.     STA    HMBL
  849.     STA    HMOVE
  850.     RTS
  851.  
  852.     ; 51
  853. DOVSYNC    JSR    WAITIM
  854.     LDA    #$02
  855.     STA    VSYNC
  856.     JSR    RAND        ; cycle LFSR
  857.     LDA    #$31        ; ball width = 8
  858.     STA    CTRLPF        ; reflect playfield
  859.     STA    WSYNC        ; set initial skeleton position
  860.     LDX    #8        ;-2
  861. SKPOS0    DEX            ;+2
  862.     BNE    SKPOS0        ;+2/3
  863.     STA    RESP0        ;46-49
  864.     LDA    #$60        ; shift left half left
  865.     STA    RESP1
  866.     STA    HMP0
  867.     LDA    #$40        ; center right half (final position)
  868.     STA    HMP1
  869.     STA    WSYNC    
  870.     STA    HMOVE
  871.     LDA    #45*76/64+1
  872.     STA    WSYNC
  873.     STA    TIM64T
  874.     LDA    #$00
  875.     STA    VSYNC
  876.     STA    HMCLR
  877.     RTS
  878.  
  879.     ORG    $1700-109
  880. SKARM1    DS    27
  881.     HEX    3F 3F
  882.     DS    80
  883. SKARM2    EQU    SKARM1+9
  884. SKARM3    EQU    SKARM1+18
  885.  
  886.     ORG    $1700
  887.     ; 80
  888. LIFELUM    DC.B    2, 2, 2, 2, 2, 2, 2, 2, 2, 2, 2, 2, 4, 4, 4, 4 
  889.     DC.B    4, 4, 4, 4, 4, 4, 4, 6, 6, 6, 6, 6, 6, 6, 6, 6
  890.     DC.B    6, 6, 6, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 10, 10
  891.     DC.B    10, 10, 10, 10, 10, 10, 10, 10, 10, 10, 12, 12, 12, 12, 12, 12 
  892.     DC.B    12, 12, 12, 12, 12, 14, 14, 14, 14, 14, 14, 14, 14, 14, 14, 14
  893.  
  894.     ; 30
  895. PVIEW4    LDA    $00,X        ; right/left step 2 subroutine
  896.     BEQ    PVIEW5        ; open found, check next
  897.     LDA    #>TYPE0        ; closed, show wall
  898.     BNE    PVIEW7
  899. PVIEW5    LDA    $01,X        ; is next open too?
  900.     BEQ    PVIEW6
  901.     LDA    #>TYPE1        ; open, show hole
  902.     BNE    PVIEW7
  903. PVIEW6    LDA    #>TYPE2        ; both open, show Y
  904. PVIEW7    INX            ; next test position
  905.     STA    $0001,Y        ; pointer MSB to RAM
  906.     LDA    #$00
  907.     STA    $0000,Y        ; LSB = 0
  908.     INY            ; next pointer position
  909.     INY
  910.     RTS
  911.  
  912.     ORG    $1800-146
  913. SKFRON2    HEX    03 03 07 07 05 05 06 06 03 03 02 02 03 03 01 01 
  914.     HEX    3F 3F 41 41 4F 4F 41 41 4F 4F 41 41 4F 4F 21 21
  915.     HEX    2F 2F 21 21 27 27 53 53 51 51 02 02 02 02 02 02 
  916.     HEX    02 02 02 02 02 02 02 02 04 04 02 02 02 02 02 02
  917.     HEX    02 02 02 02 02 02 1E 1E 00
  918. SKBACK2    HEX    03 03 07 07 07 07 07 07 03 03 03 03 03 03 01 01
  919.     HEX    3F 3F 5F 5F 4F 4F 41 41 4F 4F 41 41 4F 4F 21 21 
  920.     HEX    2F 2F 21 21 27 27 53 53 51 51 02 02 02 02 02 02 
  921.     HEX    02 02 02 02 02 02 02 02 04 04 02 02 02 02 02 02
  922.     HEX    02 02 02 02 02 02 1E 1E 00
  923.  
  924.     ORG    $1800
  925.     ; 170
  926. TITLEPF    HEX    FF4B0B7D89    ; SKELETON
  927.     HEX    115208129A
  928.     HEX    F7630912AA
  929.     HEX    81520812CA
  930.     HEX    FF4B7B1189
  931.     HEX    0000000000
  932.     HEX    0100388000    ; BY
  933.     HEX    0100488000
  934.     HEX    0A00380000
  935.     HEX    0400480000
  936.     HEX    0400380000
  937.     HEX    0000000000
  938.     HEX    FE73391910    ; ERIC BALL
  939.     HEX    124904A510
  940.     HEX    7E71043D10
  941.     HEX    124904A510
  942.     HEX    FE4B3925F7
  943.  
  944. GOT    HEX    FF FF F8 FF F8
  945.     HEX    30 00 CC 60 CC
  946.     HEX    30 3F 78 60 78
  947.     HEX    30 03 E0 60 E0
  948.     HEX    F0 FF E0 60 E0
  949.     HEX    00 00 00 00 00
  950. YOU    HEX    33 03 FC 03 FC
  951.     HEX    33 03 0C 03 0C
  952.     HEX    F3 FF 0C 03 0C
  953.     HEX    03 60 0C 03 0C
  954.     HEX    0F 60 FC FF FC
  955.     HEX    00 00 00 00 00
  956. WIN    HEX    33 03 FC 07 FC
  957.     HEX    33 63 80 1B 80
  958.     HEX    B3 9B 80 63 80
  959.     HEX    7B 07 80 83 80
  960.     HEX    37 03 FC 03 FC
  961.  
  962.     ; 13
  963. INIT    LDX    #LOADEND-LOADRAM
  964. INITL    LDA    LOADRAM-1,X    ; copy in initial values
  965.     STA    RAMLOAD-1,X
  966.     DEX
  967.     BNE    INITL
  968.     JMP    LAST
  969.  
  970.     ORG    $1900-73
  971. SKBODY2    HEX    70 70 F8 F8 B8 B8 78 78 F8 F8 78 78 D0 D0 10 10 
  972.     HEX    78 78 F8 F8 F8 F8 08 08 F8 F8 08 08 F8 F8 08 08 
  973.     HEX    38 38 08 08 38 38 38 38 38 38 10 10 10 10 10 10 
  974.     HEX    10 10 10 10 10 10 10 10 20 20 10 10 10 10 10 10 
  975.     HEX    10 10 10 10 10 10 70 70 00
  976.  
  977.     ORG    $1900
  978. MAZES    HEX    00 00 05 61 75 0B CA 51 93 01 1E 40 A8 61 C9 BA 
  979.     HEX    45 FA 1E 82 0D BD 62 24 1D E4 2A D3 9C 33 55 26 
  980.     HEX    41 C2 03 70 42 05 31 8E 5C 77 20 74 50 21 89 81 
  981.     HEX    39 36 09 95 3A 8A 40 61 D4 50 88 53 CB 67 72 16 
  982.     HEX    44 84 6A 04 45 E9 16 98 1A 23 05 37 43 58 90 29 
  983.     HEX    CA 31 D1 92 7C 43 17 64 41 84 5C 92 0B A4 13 C5 
  984.     HEX    10 3F 7D 11 C0 42 AA 66 BB 02 21 60 76 60 AA 0E 
  985.     HEX    30 F4 01 87 68 55 93 50 00 44 9F 08 C1 A8 35 40 
  986.     HEX    E9 E2 08 71 E2 43 3D 54 FB 40 76 22 96 06 52 D8 
  987.     HEX    7F 03 16 D0 5C 81 09 82 45 81 08 83 6C 41 A9 74 
  988.     HEX    46 80 68 41 3B B5 57 B2 2C B6 75 12 20 92 06 8B 
  989.     HEX    41 B9 16 C7 07 50 1B 42 21 61 58 D0 4D 31 C8 30 
  990.     HEX    14 4B 82 BA 01 F8 B6 4A 97 C9 46 71 C7 46 46 49 
  991.     HEX    86 23 57 0C 42 55 14 05 21 30 84 49 75 4C F1 30 
  992.     HEX    40 38 94 24 F3 DC 7E D3 09 CE 11 23 83 4A 62 2D 
  993.     HEX    C3 7C 97 48 C2 00 35 31 3D 40 E0 6D 33 07 94 10 
  994.  
  995.     ORG    $1A00
  996. TYPE0                ; NO OPENING
  997.     HEX    101010101010    ; MAZE0 PF0
  998.     HEX    202020202020
  999.     HEX    404040404040
  1000.     HEX    808080808080
  1001.     HEX    808080808080    ; MAZE1 PF1
  1002.     HEX    404040404040
  1003.     HEX    202020202020
  1004.     HEX    101010101010
  1005.     HEX    181818181818    ; MAZE2 PF1
  1006.     HEX    141414141414
  1007.     HEX    121212121212
  1008.     HEX    111111111111
  1009.     HEX    010101010101    ; MAZE3 PF2
  1010.     HEX    020202020202
  1011.     HEX    040404040404
  1012.     HEX    080808080808
  1013.  
  1014.     ; 36
  1015. START    SEI            ; enable interupts
  1016.     CLD            ; turn off BCD math
  1017.     LDA    #$00        ; clear zero page memory & registers
  1018.     LDX    #$44        ; start with the TIA shadow
  1019. NULL    STA    0,X
  1020.     INX
  1021.     BNE    NULL
  1022.     STX    TITLEX        ; <TITLEPF = 0
  1023.     DEX            ; set stack to bottom of RAM
  1024.     TXS
  1025.  
  1026.     STX    COLUPF        ; set up title screen
  1027.     LDA    #<GOT
  1028.     STA    TITLEND
  1029.     LDY    #13
  1030.     STY    TITLEY
  1031.     LDA    #38*76/64+1
  1032.     STA    TITLBOT
  1033.     LDA    #49*76/64+1
  1034.     STA    TITLTOP
  1035.     JMP    TITLE3
  1036.  
  1037.     HEX    F8F8F8F8F8F8    ; MAZE3 PF2
  1038.     HEX    040404040404
  1039.     HEX    020202020202
  1040.     HEX    010101010101
  1041.     HEX    111111111111    ; MAZE2 PF1
  1042.     HEX    121212121212
  1043.     HEX    141414141414
  1044.     HEX    181818181818
  1045.     HEX    1F1F1F1F1F1F    ; MAZE1 PF1
  1046.     HEX    202020202020
  1047.     HEX    404040404040
  1048.     HEX    808080808080
  1049.     HEX    808080808080    ; MAZE0 PF0
  1050.     HEX    404040404040
  1051.     HEX    202020202020
  1052.     HEX    101010101010
  1053.  
  1054.     ; 38
  1055. SKSTEP    STY    SKELY
  1056.     TXA
  1057.     BMI    SKSTEP1        ; skeleton behind
  1058.     EOR    #$FF        ; NEG
  1059.     CLC
  1060.     ADC    #$01
  1061.     BMI    SKSTEP2
  1062. SKSTEP1    ASL            ; multiply by 2
  1063. SKSTEP2    STA    SKELX
  1064.     TYA
  1065.     BPL    SKSTEP3        ; skeleton right
  1066.     CLC
  1067.     ADC    SKELX
  1068.     TAX            ; left = X + Y
  1069.     CLC
  1070.     ADC    SKELY
  1071.     TAY            ; right = X + 2Y
  1072.     RTS
  1073. SKSTEP3    LDA    SKELX
  1074.     SEC
  1075.     SBC    SKELY
  1076.     TAY            ; right = X - Y
  1077.     SEC
  1078.     SBC    SKELY
  1079.     TAX            ; left = X - 2Y
  1080.     RTS
  1081.  
  1082.     ; 46
  1083. PDIRXY    LDA    #$01        ; adjust SKELXY for PDIR
  1084.     BIT    PLAYDIR
  1085.     BEQ    PDIRXY2        ; PLAYDIR = 16 or -16
  1086.     BMI    PDIRXY1        ; PLAYDIR = -1
  1087.     LDX    SKELX        ; PLAYDIR = 1
  1088.     LDY    SKELY
  1089.     RTS
  1090. PDIRXY1    LDA    SKELX        ; rotate 180
  1091.     EOR    #$FF        ; NEG
  1092.     TAX
  1093.     INX
  1094.     LDA    SKELY
  1095.     EOR    #$FF        ; NEG
  1096.     TAY
  1097.     INY
  1098.     RTS
  1099. PDIRXY2    BMI    PDIRXY3        ; PLAYDIR = -16
  1100.     LDX    SKELY        ; PLAYDIR = 16
  1101.     LDA    SKELX        ; rotate 90
  1102.     EOR    #$FF        ; NEG
  1103.     TAY
  1104.     INY
  1105.     RTS
  1106. PDIRXY3    LDA    SKELY        ; rotate -90
  1107.     EOR    #$FF        ; NEG
  1108.     TAX
  1109.     INX
  1110.     LDY    SKELX
  1111.     RTS
  1112.  
  1113.     ; 51
  1114. SKELDIE    HEX    00 20 40 60 81 A1 C1 D2 B2 92 73 53 33 24 44 64 
  1115.     HEX    85 A5 C5 D6 B6 96 77 57 37 28 48 68 88 A9 C9 D9 
  1116.     HEX    BA 9A 7A 5B 3B 2B 4C 6C 8C AD CD DD BE 9E 7E 5F 
  1117.     HEX    3F 2F 4F
  1118.  
  1119.     ORG    $1C00-146
  1120. SKFRON1    HEX    03 03 03 07 07 07 05 05 05 06 06 06 03 03 03 
  1121.     HEX    02 02 02 03 03 03 01 01 01 3F 3F 3F 41 41 41 
  1122.     HEX    4F 4F 4F 41 41 41 4F 4F 4F 41 41 41 4F 4F 4F 
  1123.     HEX    21 21 21 2F 2F 2F 21 21 21 27 27 27 53 53 53
  1124.     HEX    51 51 51 02 02 02 02 02 02 02 02 02 02 02 02 
  1125.     HEX    02 02 02 02 02 02 02 02 02 04 04 04 02 02 02 
  1126.     HEX    02 02 02 02 02 02 02 02 02 02 02 02 02 02 02 
  1127.     HEX    1E 1E 1E 00
  1128. SKFRON3    HEX    03 07 05 06 03 02 03 01 3F 41 4F 41 4F 41 4F 21 2F 21 27 
  1129.     HEX    53 51 02 02 02 02 02 02 02 04 02 02 02 02 02 02 1E 00
  1130.  
  1131.     ORG    $1C00
  1132. TYPE1                ; OPENING
  1133.     HEX    000000000000    ; MAZE0 PF0
  1134.     HEX    000000000000
  1135.     HEX    000000000000
  1136.     HEX    F0F0F0F0F0F0
  1137.     HEX    000000000000    ; MAZE1 PF1
  1138.     HEX    000000000000
  1139.     HEX    000000000000
  1140.     HEX    F0F0F0F0F0F0
  1141.     HEX    101010101010    ; MAZE2 PF1
  1142.     HEX    101010101010
  1143.     HEX    101010101010
  1144.     HEX    1F1F1F1F1F1F
  1145.     HEX    000000000000    ; MAZE3 PF2
  1146.     HEX    000000000000
  1147.     HEX    000000000000
  1148.     HEX    0F0F0F0F0F0F
  1149.  
  1150.     ; 36
  1151. SKPOSXY    LDA    SKELPOS        ; change SKPOS-PLAYPOS to SKELX+SKELY
  1152.     SEC
  1153.     SBC    PLAYPOS
  1154.     STA    SKELX
  1155.     LSR
  1156.     LSR
  1157.     LSR
  1158.     LSR
  1159.     BIT    TESTBIT        ; negative?
  1160.     BEQ    SKXY2
  1161.     ORA    #$F0
  1162. SKXY2    STA    SKELY
  1163.     LDA    SKELX
  1164.     BIT    TESTBIT        ; negative?
  1165.     BEQ    SKXY3
  1166.     INC    SKELY
  1167.     ORA    #$F0
  1168.     BMI    SKXY4
  1169. SKXY3    AND    #$0F
  1170. SKXY4    STA    SKELX
  1171.     RTS
  1172.  
  1173.     HEX    FFFFFFFFFFFF    ; MAZE3 PF2
  1174.     HEX    040404040404
  1175.     HEX    020202020202
  1176.     HEX    010101010101
  1177.     HEX    1F1F1F1F1F1F    ; MAZE2 PF1
  1178.     HEX    121212121212
  1179.     HEX    141414141414
  1180.     HEX    181818181818
  1181.     HEX    FFFFFFFFFFFF    ; MAZE1 PF1
  1182.     HEX    202020202020
  1183.     HEX    404040404040
  1184.     HEX    808080808080
  1185.     HEX    F0F0F0F0F0F0    ; MAZE0 PF0
  1186.     HEX    404040404040
  1187.     HEX    202020202020
  1188.     HEX    101010101010
  1189.  
  1190.     ; 28
  1191. GOTYOU    LDY    #<WIN-5
  1192.     LDX    #<GOT
  1193.     BNE    GOTYOU2
  1194. YOUWIN    LDY    #<SKBODY3
  1195.     LDX    #<YOU
  1196. GOTYOU2    STY    TITLEND
  1197.     STX    TITLEX
  1198.     LDY    #20
  1199.     STY    TITLEY
  1200.     LDA    #39*76/64+1
  1201.     STA    TITLBOT
  1202.     LDA    #49*76/64+1
  1203.     STA    TITLTOP
  1204.     BNE    TITLE1
  1205.  
  1206.     ; 110
  1207. TITLE3    LDA    #$02
  1208.     STA    VSYNC
  1209.     STA    WSYNC
  1210.     JSR    RAND        ; cycle LFSR
  1211.     STA    WSYNC    
  1212.     LDA    TITLTOP
  1213.     STA    WSYNC
  1214.     STA    TIM64T
  1215.     LDA    #$00
  1216.     STA    VSYNC
  1217.     LDX    TITLEX
  1218. TITLE2    JSR    WAITIM
  1219. TITLE    STA    WSYNC
  1220.     LDA    TITLEPF+1,X    ;-4
  1221.     STA    PF1        ;-7
  1222.     LDA    TITLEPF+2,X    ;-11
  1223.     STA    PF2        ;-14
  1224.     LDA    TITLEPF,X    ;-18
  1225.     STA    PF0        ;-21
  1226.     ASL            ;-23
  1227.     ASL            ;-25
  1228.     ASL            ;-27
  1229.     ASL            ;-31
  1230.     STA    PF0        ;-34
  1231.     LDA    TITLEPF+3,X    ;-38
  1232.     STA    PF1        ;-41
  1233.     LDA    TITLEPF+4,X    ;-45
  1234.     DEY            ;-47
  1235.     BNE    TITLE0        ;-49/50
  1236.     LDY    TITLEY        ;-52
  1237.     INX            ;-54
  1238.     INX            ;-56
  1239.     INX            ;-58
  1240.     INX            ;-60
  1241.     INX            ;-62
  1242. TITLE0    STA    PF2        ;50/62-53/65
  1243.     CPX    TITLEND        ;-67
  1244.     BNE    TITLE        ;-69/70
  1245.     LDA    TITLBOT        ;-72
  1246.     STA    WSYNC        ;-0
  1247.     STA    TIM64T        ;-4
  1248.     LDA    #0
  1249.     STA    PF0
  1250.     STA    PF1
  1251.     STA    PF2
  1252.     STA    AUDV0
  1253.     STA    AUDV1
  1254.     LDA    SWCHB        ; check reset/select
  1255.     AND    #$03
  1256.     CMP    #$03
  1257.     BEQ    TITLE1
  1258.     JMP    INIT
  1259. TITLE1    JSR    WAITIM
  1260.     BEQ    TITLE3
  1261.  
  1262.     ORG    $1E00-146
  1263. SKBACK1    HEX    03 03 03 07 07 07 07 07 07 07 07 07 03 03 03 
  1264.     HEX    03 03 03 03 03 03 01 01 01 3F 3F 3F 5F 5F 5F 
  1265.     HEX    4F 4F 4F 41 41 41 4F 4F 4F 41 41 41 4F 4F 4F 
  1266.     HEX    21 21 21 2F 2F 2F 21 21 21 27 27 27 53 53 53
  1267.     HEX    51 51 51 02 02 02 02 02 02 02 02 02 02 02 02 
  1268.     HEX    02 02 02 02 02 02 02 02 02 04 04 04 02 02 02 
  1269.     HEX    02 02 02 02 02 02 02 02 02 02 02 02 02 02 02 
  1270.     HEX    1E 1E 1E 00
  1271. SKBACK3    HEX    03 07 07 07 03 03 03 01 3F 5F 4F 41 4F 41 4F 21 2F 21 27 
  1272.     HEX    53 51 02 02 02 02 02 02 02 04 02 02 02 02 02 02 1E 00
  1273.  
  1274.     ORG    $1E00
  1275. TYPE2                ; CORRIDOR
  1276.     HEX    000000000000    ; MAZE0 PF0
  1277.     HEX    000000000000
  1278.     HEX    000000000000
  1279.     HEX    808080808080
  1280.     HEX    000000000000    ; MAZE1 PF1
  1281.     HEX    000000000000
  1282.     HEX    000000000000
  1283.     HEX    101010101010
  1284.     HEX    101010101010    ; MAZE2 PF1
  1285.     HEX    101010101010
  1286.     HEX    101010101010
  1287.     HEX    111111111111
  1288.     HEX    000000000000    ; MAZE3 PF2
  1289.     HEX    000000000000
  1290.     HEX    000000000000
  1291.     HEX    080808080808
  1292.  
  1293.     ; 8
  1294. WAITIM    STA    WSYNC        ;-0
  1295.     LDA    INTIM        ;-4
  1296.     BNE    WAITIM        ; wait for bottom of frame
  1297.     RTS
  1298.  
  1299.     ; 14
  1300. LOADRAM    DC.B    50        ; SKELDEL
  1301.     DC.B    50        ; SKELPER
  1302.     DC.B    25        ; SKELSEC
  1303.     DC.B    40        ; SKELMIN
  1304.     DC.B    40        ; SKELHRS
  1305. LOADDEL    EQU    .
  1306.     DC.B    $00        ; PLAYPOS
  1307.     DC.B    1        ; PLAYDIR
  1308.     DC.B    16        ; PLAYRIG
  1309.     DC.B    $88        ; SKELPOS
  1310.     DC.B    1        ; SKELDIR
  1311.     DC.B    16        ; SKELRIG
  1312. LOADLVL    EQU    .
  1313.     DC.B    $08        ; TESTBIT
  1314.     DC.B    1        ; LVLMASK
  1315.     DC.B    $23        ; MAZECOL
  1316. LOADEND    EQU    .
  1317.  
  1318.     ; 14
  1319. PVIEW3    TAY            ; right/left step 1 subroutine
  1320.     LDA    LVLMASK        ; move bits from ROM to RAM
  1321.     AND    MAZES,Y
  1322.     STA    $00,X
  1323.     INX
  1324.     TYA
  1325.     CLC            ; move forward one step
  1326.     ADC    PLAYDIR
  1327.     RTS
  1328.  
  1329.     HEX    FFFFFFFFFFFF    ; MAZE3 PF2
  1330.     HEX    040404040404
  1331.     HEX    020202020202
  1332.     HEX    010101010101
  1333.     HEX    1F1F1F1F1F1F    ; MAZE2 PF1
  1334.     HEX    121212121212
  1335.     HEX    141414141414
  1336.     HEX    181818181818
  1337.     HEX    FFFFFFFFFFFF    ; MAZE1 PF1
  1338.     HEX    202020202020
  1339.     HEX    404040404040
  1340.     HEX    808080808080
  1341.     HEX    F0F0F0F0F0F0    ; MAZE0 PF0
  1342.     HEX    404040404040
  1343.     HEX    202020202020
  1344.     HEX    101010101010
  1345.  
  1346.     ORG    $1FF8-146
  1347. SKBODY1    HEX    70 70 70 F8 F8 F8 B8 B8 B8 78 78 78 F8 F8 F8 
  1348.     HEX    78 78 78 D0 D0 D0 10 10 10 78 78 78 F8 F8 F8 
  1349.     HEX    F8 F8 F8 08 08 08 F8 F8 F8 08 08 08 F8 F8 F8 
  1350.     HEX    08 08 08 38 38 38 08 08 08 38 38 38 38 38 38 
  1351.     HEX    38 38 38 10 10 10 10 10 10 10 10 10 10 10 10 
  1352.     HEX    10 10 10 10 10 10 10 10 10 20 20 20 10 10 10 
  1353.     HEX    10 10 10 10 10 10 10 10 10 10 10 10 10 10 10 
  1354.     HEX    70 70 70 00
  1355. SKBODY3    HEX    70 F8 B8 78 F8 78 D0 10 78 F8 F8 08 F8 08 F8 08 38 08 38
  1356.     HEX    38 38 10 10 10 10 10 10 10 20 10 10 10 10 10 10 70 00
  1357.  
  1358.     ORG    $1FF8        ; Supercharger bankswitch
  1359.     DC.B    "1SL1"
  1360.  
  1361.     ORG    $1FFC        ; end of 4K cart
  1362.     DC.W    START        ; reset vector
  1363.     DC.W    START        ; IRQ vector
  1364.  
  1365.  
  1366.